【解説】 【MQL5 community】 WPR (Larry Williams' Percent Range): %ROscillator(オシレータ)と呼ばれることもある。 この手法は投資コンテストで資金を1年間で１００倍以上にしたことで有名なラリー・ウィリアムズが開発したものです。 これはレンジ相場の時に有効といわれ、買われ過ぎ、売られ過ぎを判断する指標である。 これはストキャスティクスを改良したもので、 ストキャスティクスの％Kの部分の最安値を最高値に置き換えたものです。
【計算法】
−１００×（N期間の最高値ー現在の価格）／（N期間の最高値−N期間の最安値）
【シグナル】
数値が−２０％以上、あるいは０％に張り付いたら反転下降の目安なので「売り」サイン
−８０％以下、または−１００％へ張り付いたら反転上昇の目安になるので「買い」サイン
一定のレンジを抜いた地点を売買サインとしてみることも出来ます。
//+------------------------------------------------------------------+
//| WPR.mq5 |
//| Copyright 2009, MetaQuotes Software Corp. |
//| http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "2009, MetaQuotes Software Corp."
#property link "http://www.mql5.com"
#property description "Larry Williams' Percent Range"
//---- indicator settings
#property indicator_separate_window
#property indicator_level1 -20.0
#property indicator_level2 -80.0
#property indicator_levelstyle STYLE_DOT
#property indicator_levelcolor Silver
#property indicator_levelwidth 1
#property indicator_maximum 0.0
#property indicator_minimum -100.0
#property indicator_buffers 1
#property indicator_plots 1
#property indicator_type1 DRAW_LINE
#property indicator_color1 DodgerBlue
//---- input parameters
input int InpWPRPeriod=14; // Period
//---- buffers
double ExtWPRBuffer[];
//--- global variables
int ExtPeriodWPR;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
void OnInit()
{
//--- check for input value
if(InpWPRPeriod＜3)
{
ExtPeriodWPR=14;
Print("Incorrect InpWPRPeriod value. Indicator will use value=",ExtPeriodWPR);
}
else ExtPeriodWPR=InpWPRPeriod;
//---- name for DataWindow and indicator subwindow label
IndicatorSetString(INDICATOR_SHORTNAME,"%R"+"("+string(ExtPeriodWPR)+")");
//---- indicator's buffer
SetIndexBuffer(0,ExtWPRBuffer);
PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,ExtPeriodWPR-1);
//--- digits
IndicatorSetInteger(INDICATOR_DIGITS,2);
//----
}
//+------------------------------------------------------------------+
//| Williams・Percent Range |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,const int prev_calculated,
const datetime &Time[],
const double &Open[],
const double &High[],
const double &Low[],
const double &Close[],
const long &TickVolume[],
const long &Volume[],
const int &Spread[])
{
//---- insufficient data
if(rates_total＜ExtPeriodWPR)
return(0);
//--- start working
int i=prev_calculated-1;
//--- correct position
if(i＜ExtPeriodWPR-1) i=ExtPeriodWPR-1;
//--- main cycle
while(i＜rates_total)
{
//--- calculate maximum High
double dMaxHigh=MaxAr(High,ExtPeriodWPR,i);
//--- calculate minimum Low
double dMinLow=MinAr(Low,ExtPeriodWPR,i);
//--- calculate WPR
if(dMaxHigh!=dMinLow)
ExtWPRBuffer[i]=-(dMaxHigh-Close[i])*100/(dMaxHigh-dMinLow);
else
ExtWPRBuffer[i]=ExtWPRBuffer[i-1];
//--- increment i for next iteration
i++;
}
//--- return new prev_calculated value
return(rates_total);
}
//+------------------------------------------------------------------+
//| Maximum High |
//+------------------------------------------------------------------+
double MaxAr(const double &array[],int period,int cur_position)
{
double Highest=array[cur_position];
for(int i=cur_position-1;i>cur_position-period;i--)
{
if(Highest＜array[i]) Highest=array[i];
}
return(Highest);
}
//+------------------------------------------------------------------+
//| Minimum Low |
//+------------------------------------------------------------------+
double MinAr(const double &array[],int period,int cur_position)
{
double Lowest=array[cur_position];
for(int i=cur_position-1;i>cur_position-period;i--)
{
if(Lowest>array[i]) Lowest=array[i];
}
return(Lowest);
}
//+------------------------------------------------------------------+
【表示結果】
Back to Meta Trader